Price-Volume-Mix
Revenue on the demo orders grew +$7.87M from 2024 to 2025. A price-volume-mix bridge splits that into selling more, selling a richer mix, and charging more. Measured part by part, almost none of it is price.
The Grain Decides What Counts as Price
With the same items in both years, volume is the same at any grain: the change in units, priced at last year's average. (A part that is new this year sits in the new and lost bucket at part grain, but inside an existing family it counts as volume at family grain.) Mix and price are not. The coarser the grain, the more of the mix shift lands in "price", because a family or company average price rises when customers buy more of the expensive parts, even if no part's price moved.
| Grain | Volume | Mix | Price |
|---|---|---|---|
| Part (200) | +$6.48M | +$1.34M | +$52K |
| Product family (5) | +$6.48M | +$1.16M | +$226K |
| Company total | +$6.48M | $0 | +$1.39M |
A commercial team reading the company-grain bridge would credit pricing with +$1.39M. Part by part, pricing moved +$52K; the rest is customers buying a different mix. Decompose at the grain where a price is actually set, which in a plant is usually the part or the part and customer.
The DAX
The measures iterate parts sold in both periods, price each at its own average last year, and compare. Use them on a card or in a table by family; each row recomputes over the parts inside it, so the family rows show part-grain effects, not family-grain ones. Price adds up across rows, because it is a sum over parts. Volume and mix do not: a shift from one family to another is mix at the total but volume inside each family row, so the family rows' volume and mix won't sum to the total's.
Revenue = SUMX ( fact_orders, fact_orders[qty] * fact_orders[unit_price] )
Units = SUM ( fact_orders[qty] )
Revenue PY = CALCULATE ( [Revenue], SAMEPERIODLASTYEAR ( dim_date[date] ) )
Units PY = CALCULATE ( [Units], SAMEPERIODLASTYEAR ( dim_date[date] ) )
-- Like-for-like parts: sold in both periods. Each part is priced at its own
-- average selling price last year, which is what keeps mix out of price.
Revenue at PY Prices =
SUMX (
FILTER ( VALUES ( dim_product[part_id] ), [Units] > 0 && [Units PY] > 0 ),
[Units] * DIVIDE ( [Revenue PY], [Units PY] )
)
Volume Effect =
VAR Parts = FILTER ( VALUES ( dim_product[part_id] ), [Units] > 0 && [Units PY] > 0 )
VAR Q0 = SUMX ( Parts, [Units PY] )
VAR Q1 = SUMX ( Parts, [Units] )
RETURN ( Q1 - Q0 ) * DIVIDE ( SUMX ( Parts, [Revenue PY] ), Q0 )
Mix Effect =
VAR Parts = FILTER ( VALUES ( dim_product[part_id] ), [Units] > 0 && [Units PY] > 0 )
VAR Q0 = SUMX ( Parts, [Units PY] )
VAR Q1 = SUMX ( Parts, [Units] )
RETURN [Revenue at PY Prices] - Q1 * DIVIDE ( SUMX ( Parts, [Revenue PY] ), Q0 )
Price Effect =
VAR Parts = FILTER ( VALUES ( dim_product[part_id] ), [Units] > 0 && [Units PY] > 0 )
RETURN SUMX ( Parts, [Revenue] ) - [Revenue at PY Prices]
-- Whatever is left: parts sold in only one of the two periods
New and Lost Parts =
[Revenue] - [Revenue PY] - [Volume Effect] - [Mix Effect] - [Price Effect]