OEE Across Lines
A common way to build OEE in DAX is to multiply Availability, Performance and Quality, each summed in units. On one line that is exact. Across lines with different ideal rates it drifts. On the demo dataset the company figure reads 65.1% when the lines actually ran at 62.8%.
The Numbers
Every figure below is computed from fact_production_hourly (155,340 line hours)
when the site is built. Each hour is 60 planned minutes, and run time is 60 minus the downtime minutes.
| Line | Family | Ideal rate (uph) | Availability | Performance | Quality | OEE | Share of units |
|---|---|---|---|---|---|---|---|
| PDX-01 | Enclosures | 50 | 87.3% | 73.4% | 95.8% | 61.3% | 2.8% |
| PDX-02 | Enclosures | 43 | 86.7% | 71.1% | 95.8% | 59.0% | 1.4% |
| PDX-03 | Panel Assemblies | 28 | 86.7% | 68.6% | 94.8% | 56.4% | 0.9% |
| PDX-04 | Brackets | 175 | 86.6% | 74.9% | 97.7% | 63.4% | 6.0% |
| PDX-05 | Cable Management | 85 | 86.7% | 81.4% | 98.2% | 69.3% | 3.2% |
| BOI-01 | Fasteners | 693 | 87.5% | 75.5% | 98.8% | 65.3% | 39.9% |
| BOI-02 | Fasteners | 640 | 86.9% | 82.4% | 98.8% | 70.8% | 24.2% |
| BOI-03 | Brackets | 182 | 86.8% | 61.3% | 97.8% | 52.0% | 5.1% |
| BOI-04 | Cable Management | 87 | 87.1% | 73.7% | 98.2% | 63.1% | 3.0% |
| RNO-01 | Enclosures | 44 | 86.9% | 80.2% | 95.8% | 66.8% | 1.6% |
| RNO-02 | Panel Assemblies | 22 | 87.0% | 72.1% | 94.8% | 59.5% | 0.7% |
| RNO-03 | Brackets | 194 | 87.6% | 76.0% | 97.8% | 65.0% | 11.2% |
| Level | Unit-pooled Quality | Unit-pooled OEE | Time-based Quality | Time-based OEE | Overstated by |
|---|---|---|---|---|---|
| Portland Plant | 97.1% | 63.3% | 96.4% | 61.8% | 1.5 points |
| Boise Plant | 98.7% | 65.7% | 98.5% | 63.1% | 2.5 points |
| Reno Plant | 97.4% | 64.8% | 96.4% | 64.0% | 0.8 points |
| Company | 98.3% | 65.1% | 97.1% | 62.8% | 2.3 points |
Try a Different Mix
- Unit-pooled OEE
- 65.1%
- Time-based OEE
- 62.8%
- Difference
- 2.3 points
Why It Drifts
OEE is a ratio of time: the minutes spent making good parts at ideal speed, over planned minutes. Summing units instead of minutes weights each line by how many parts it makes, not by how long it ran. The two fastener lines make 64% of all units in 19% of the planned time, and they also have the best quality. Unit-pooled Quality is mostly their quality, so it reads 98.3% against 97.1% measured in time.
The direction depends on the data. Pooling overstates here because the fastest lines also have the best quality; where the high-volume lines are the worst, it understates. Either way the figure stops meaning time.
Availability is already in minutes, so it is the same either way. Performance and Quality are where the weighting slips in, and the error compounds because the three are multiplied.
The correct company number is the planned-time-weighted average of the line OEEs. A plain average of the twelve lines gives 62.7%, which is closer but still wrong, since a two-shift line counts as much as a three-shift one.
DAX That Adds Up
Put every component in minutes at the line's ideal rate. Then Availability x Performance x Quality equals OEE at the line, the plant and the company, and the three components still explain where the time went.
The two ideal-minutes measures iterate the distinct ideal rates rather than the fact rows. CALCULATE turns each rate into
a filter, so the storage engine sums units for every line at that rate at once, and DIVIDE runs 12 times instead
of once per hour of history. Two lines that share a rate are summed together, which gives the same minutes as dividing each line separately.
Planned Minutes = COUNTROWS ( fact_production_hourly ) * 60
Run Minutes =
[Planned Minutes] - SUM ( fact_production_hourly[downtime_minutes] )
-- Minutes the units would take at the line's ideal rate, summed per rate
Ideal Minutes Produced =
SUMX (
VALUES ( dim_line[ideal_rate_uph] ),
DIVIDE (
CALCULATE ( SUM ( fact_production_hourly[units_produced] ) ) * 60,
dim_line[ideal_rate_uph]
)
)
Ideal Minutes Good =
SUMX (
VALUES ( dim_line[ideal_rate_uph] ),
DIVIDE (
CALCULATE (
SUM ( fact_production_hourly[units_produced] )
- SUM ( fact_production_hourly[scrap_units] )
) * 60,
dim_line[ideal_rate_uph]
)
)
Availability % = DIVIDE ( [Run Minutes], [Planned Minutes] )
Performance % = DIVIDE ( [Ideal Minutes Produced], [Run Minutes] )
Quality % = DIVIDE ( [Ideal Minutes Good], [Ideal Minutes Produced] )
-- Equals Availability x Performance x Quality at every level
OEE % = DIVIDE ( [Ideal Minutes Good], [Planned Minutes] )